Свет мой, 1С, скажи, наращение покажи…

Публикация № 1332827

Учет и отчетность - Оптовая торговля

Ключевые слова: наращение показатели продажи приведение

В типовой 1С:Бухгалтерия 8 на начальной странице есть различные информационные панели, в том числе, панель «Продажи». Данная панель показывает текущие показатели по продажам в сравнении с показателями аналогичного периода прошлого года. Правда, что это хорошо, но эта правда не совсем правда…

В типовой 1С:Бухгалтерия 8 на начальной странице есть различные информационные панели: «Задачи организации»,  «Покупатели», «Продажи» и т.д. На этом фоне выделяется панель «Продажи», которая показывает текущие показатели по продажам и индикаторы (больше/меньше) в сравнение с показателями аналогичного периода прошлого года. Вроде бы всё хорошо и это правда, но что-то подсказывает, что это не совсем правда.

Не будем углубляться в финансовую математику, скажем только про зависимость стоимости денежных средств от времени. Теперь очень просто: 100 руб. год назад не равны по своей покупательской способности 100 руб. на текущий момент (инфляция и всё такое). И тут на ум приходят понятия «дисконтирование» (определение стоимости денежного потока путём приведения стоимости всех выплат к определённому моменту времени) и «наращение» (приведение стоимости денежных средств к моменту в будущем). Наращение ещё называют компаундированием. Более подробно об этом можно прочитать, например, здесь. После недолгих размышлений приходим к мысли, что нам необходимо именно наращение, как приведение прошлогодних денежных показателей к будущему (то есть к настоящему времени). В общем, назад в будущее.


Для реализации сравнения «реальных» денежных показателей с текущим моментом можно воспользоваться механизмом создания расширения и в захваченную процедуру «ДанныеПродажи» (общий модуль «МониторРуководителя») вставить алгоритм пересчета прошлых показателей с учетом наращения. Например, вот так:


&Вместо("ДанныеПродажи")
Функция Наращение_ДанныеПродажи(Параметры)

	Данные = Новый Структура;
	Данные.Вставить("ТекущийМесяц", 0);
	Данные.Вставить("ТекущийМесяцОтклонение", 0);
	Данные.Вставить("ТекущийМесяцСНачалаГода", 0);
	Данные.Вставить("ТекущийМесяцСНачалаГодаОтклонение", 0);
	Данные.Вставить("ПрошлыйМесяц", 0);
	Данные.Вставить("ПрошлыйМесяцОтклонение", 0);
	Данные.Вставить("ПрошлыйМесяцСНачалаГода", 0);
	Данные.Вставить("ПрошлыйМесяцСНачалаГодаОтклонение", 0);

	РазделыМонитора = Новый Массив;
	РазделыМонитора.Добавить(Перечисления.РазделыМонитораРуководителя.ПродажиПоКонтрагентам);

	ДанныеРазделовМонитора = ПолучитьДанныеРазделовМонитора(
	Параметры.Организация, РазделыМонитора, Параметры.ВариантОкругления, Параметры.ПоказыватьСравнениеСПрошлымГодом);

	Если ДанныеРазделовМонитора = Неопределено Тогда
		Возврат Данные;
	КонецЕсли;
	
	//дельта стало теперь 2020-11-20 НАЧАЛО
	Если Параметры.СУчетомНаращения Тогда
		//1 - Необходимо прошлые периды пересчитать с учетом коэффициента наращения
		
		//формула для нахождения коэффициента наращения
		//КоэффициентНаращения = Pow((1 + ПроцентнаяСтавка),НомерПериода);
		
		//в качестве коэффициента наращения можно, например, использовать уровень инфляции за прошлый год
		ПроцентнаяСтавка = Параметры.ПроцентнаяСтавка / 100;
		
		//Номер периода - 1, т.к. смотрим на 1 год назад
		НомерПериода = 1;
		
		КоэффициентНаращения = Pow((1 + ПроцентнаяСтавка), НомерПериода);
		
		Для Каждого ТекСтрока Из ДанныеРазделовМонитора Цикл 
			//приведенная сумма
			ТекСтрока.СуммаПрошлыйПериод = ТекСтрока.СуммаПрошлыйПериод * КоэффициентНаращения; 
			
			//приведенное отклонение
			ТекСтрока.Отклонение = Окр((ТекСтрока.Сумма/ТекСтрока.СуммаПрошлыйПериод - 1)*100,2);
			
		КонецЦикла;
		//2 - Необходимо пересчитать отклонение
	КонецЕсли;
	//дельта стало теперь 2020-11-20 КОНЕЦ

	ДанныеРазделовМонитора.Индексы.Добавить("РазделМонитора, Порядок");

	Отбор = Новый Структура;
	Отбор.Вставить("РазделМонитора", Перечисления.РазделыМонитораРуководителя.ПродажиПоКонтрагентам);
	Отбор.Вставить("Порядок", 0);

	// Текущий месяц
	Отбор.Порядок = Отчеты.Продажи.ПорядокТекущегоМесяца();
	НайденныеСтроки = ДанныеРазделовМонитора.НайтиСтроки(Отбор);
	Если НайденныеСтроки.Количество() > 0 Тогда
		Данные.Вставить("ТекущийМесяц", НайденныеСтроки[0].Сумма);
		Данные.Вставить("ТекущийМесяцОтклонение", НайденныеСтроки[0].Отклонение);
	КонецЕсли;

	// С начала года
	Отбор.Вставить("Порядок", Отчеты.Продажи.ПорядокТекущегоМесяцаСНачалаГода());
	НайденныеСтроки = ДанныеРазделовМонитора.НайтиСтроки(Отбор);
	Если НайденныеСтроки.Количество() > 0 Тогда
		Данные.Вставить("ТекущийМесяцСНачалаГода", НайденныеСтроки[0].Сумма);
		Данные.Вставить("ТекущийМесяцСНачалаГодаОтклонение", НайденныеСтроки[0].Отклонение);
	КонецЕсли;

	// Прошлый месяц
	Отбор.Порядок = Отчеты.Продажи.ПорядокПрошлогоМесяца();
	НайденныеСтроки = ДанныеРазделовМонитора.НайтиСтроки(Отбор);
	Если НайденныеСтроки.Количество() > 0 Тогда
		Данные.Вставить("ПрошлыйМесяц", НайденныеСтроки[0].Сумма);
		Данные.Вставить("ПрошлыйМесяцОтклонение", НайденныеСтроки[0].Отклонение);
	КонецЕсли;

	// С начала года по конец прошлого месяца
	Отбор.Порядок = Отчеты.Продажи.ПорядокПрошлогоМесяцаСНачалаГода();
	НайденныеСтроки = ДанныеРазделовМонитора.НайтиСтроки(Отбор);
	Если НайденныеСтроки.Количество() > 0 Тогда
		Данные.Вставить("ПрошлыйМесяцСНачалаГода", НайденныеСтроки[0].Сумма);
		Данные.Вставить("ПрошлыйМесяцСНачалаГодаОтклонение", НайденныеСтроки[0].Отклонение);
	КонецЕсли;

	Возврат Данные;

КонецФункции

 

Пример такой доработки (вместе с возможностью динамически пересчитывать показатели при изменении) приложен к публикации в виде расширения. Разработка и тестирование осуществлялись на базе типовой «1С: Бухгалтерия предприятия, редакция 3.0 (3.0.83.37)» и платформе 1С:Предприятие 8.3 (8.3.16.1063).

Скачать файлы

Наименование Файл Версия Размер
Расширение - Панель Продажи с учетом наращения

.cfe 54,23Kb
0
.cfe 1.0 54,23Kb Скачать

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Поручик 4460 26.11.20 11:24 Сейчас в теме
2. delta 363 26.11.20 11:34 Сейчас в теме
(1) Мне думается, что не в курсе.
Хотя может быть и в курсе, но не хотят портить показатели у пользователей :-)
Оставьте свое сообщение